#include "colors.inc"    
#include "metals.inc"
#include "finish.inc"
#include "math.inc"
#include "automobile_bug.inc"
global_settings
{
  max_trace_level 10
ambient_light rgb<1, 1, 1>
}
camera {
    location <0, 12 ,-80>
    look_at  <0, 0, 0>
    angle 28
}
//light_source { <4,4, -5> color White}
light_source { <0,+40, -30> color White}
#declare dangle=clock*360;
#declare rangle=clock*2*pi;
#declare courserad=16;
#declare coursewidth=4;
#declare xnow=-courserad*cos(rangle);
#declare znow=-courserad*sin(rangle);
//arrow
#declare arrow=merge{
        cylinder{<0,0,0>,<.6,0,0>,.05}
        cone { <.6, 0, 0>, .2, <1, 0, 0>, .0000001 }
}

union{
        object{automobile_bug scale 2}
          text {
            ttf "Times" "f" .005, 0
            scale 2.5
            translate <-.25,0,0>
            rotate y*dangle 
            translate 4.5*x+.7*y
            pigment{ color rgb <.9,.1,.1> } 
            finish { phong .8 phong_size 200 ambient 1.2 } no_shadow
          }        
          object{arrow scale 2 translate 2*x+.8*y pigment{ color rgb <.9,.1,.1>} 
          finish { phong .8 phong_size 200 ambient 1.2 } no_shadow}

          text {
            ttf "Times" "w" .005, 0
            scale 2.5
            translate <-.9,0,0>
            rotate y*dangle 
            translate -4.5*y
            pigment{ color Yellow } 
            finish { phong .8 phong_size 200 ambient 1.4 } no_shadow
          }
        object{arrow scale 2 rotate -z*90 translate -1*y pigment{ color Yellow } 
        finish { phong .8 phong_size 200 ambient 1.4 } no_shadow}

          text {
            ttf "Times" "N" .005, 0
            scale 2.5
            translate <-.7,0,0>
            rotate y*dangle 
            translate +6*y-.25*x
            pigment{ color rgb <.2,.2,1> } 
            finish { phong .8 phong_size 200 ambient 1.4 } no_shadow
          }
          object{arrow scale 2.5 rotate z*90 translate 2.5*y pigment{ color rgb <.2,.2,1> } 
          finish { phong .8 phong_size 200 ambient 1.4 } no_shadow}

        translate -x*courserad rotate  -y*dangle 
}
sky_sphere {    //sky
    pigment {
      gradient y
      color_map {
        [0.000 0.002 color rgb <1.0, 1, 0.8>
                     color rgb <1.0, 1, 0.8>]
        [0.002 0.200 color rgb <0.8, 0.8, 0.6>
                     color rgb <0.2, 0.2, 0.8>]
      }
      scale 2
      translate -1
    }
pigment {
      bozo
      turbulence 0.65
      octaves 6
      omega 0.7
      lambda 2
      color_map {
          [0.0 0.1 color rgb <0.85, 0.85, 0.85>
                   color rgb <0.75, 0.75, 0.75>]
          [0.1 0.5 color rgb <0.75, 0.75, 0.75>
                   color rgbt <1, 1, 1, 1>]
          [0.5 1.0 color rgbt <1, 1, 1, 1>
                   color rgbt <1, 1, 1, 1>]
      }
      scale <0.2, 0.5, 0.2>
    }

    rotate -105*x
    rotate y*180
  }
   plane {  //grassy plain
    y, -.3
    texture {
      pigment { color rgbt <.6,1,.7,.6> }
      normal { bumps 0.2 scale 0.02 }
      finish { phong 50 ambient .6 diffuse .4}
    }    
  }

  plane {   //background to prevent sky from bleeding through transparant grass
    y, -10 pigment { color Black }    }    


difference{    //track
        cylinder { <0, 0, 0>, <0, .02, 0>, courserad+coursewidth/2 }
        cylinder { <0, -.1, 0>, <0, .2, 0>, courserad-coursewidth/2 }
    texture {
      pigment { color rgbt <.3,.3,.3,.6> }
      normal { bumps 0.3 scale 0.2 }
      finish { phong 210 ambient .3 }
    }
    no_shadow    
}