#include "colors.inc"    
#include "metals.inc"
#include "finish.inc"
#include "math.inc"
#include "automobile_bug.inc"
global_settings
{
  max_trace_level 10
ambient_light rgb<1, 1, 1>
}
camera {
    location <0, 12 ,-80>
    look_at  <0, 0, 0>
    angle 28
}
#declare dangle=clock*360;
#declare rangle=clock*2*pi;
#declare courserad=16;
#declare coursewidth=5;
#declare xnow=-courserad*cos(rangle);
#declare znow=-courserad*sin(rangle);
#declare bangle = 30;
#declare brangle = bangle*pi/180;

#declare h=coursewidth*tan(brangle);

//arrow
#declare arrow=merge{
        cylinder{<0,0,0>,<.6,0,0>,.05}
        cone { <.6, 0, 0>, .2, <1, 0, 0>, .0000001 }
}

//light_source { <4,4, -5> color White}
light_source { <0,+40, -50> color White}
union{
        union{
                object{automobile_bug scale 2}
                object{arrow scale 2/cos(brangle) rotate z*90 translate 3.1*y no_shadow
                    pigment{ color rgb <.0,.0,1> } 
                    finish { phong .2 phong_size 20 ambient 1.2 }
        }
        rotate -z*bangle translate y*h/2}
        union{
                object{arrow scale 1.8 translate 1.8*x+.5*y pigment{ color Orange } 
                finish { phong .8 phong_size 200 ambient 1 }}
                  text {
                    ttf "Times" "Fnet" .005, 0
                    scale 1.8
                    translate <-1.75,0,0>
                    rotate y*dangle 
                    translate 6*x+.6*y
                    pigment{ color Orange } 
                    finish { phong .8 phong_size 200 ambient 1 }
                    
                  }
                object{arrow scale 1.6 rotate -z*90 translate -1*y pigment{ color Yellow } 
                finish { phong .8 phong_size 200 ambient 1.5 }}
                  text {
                    ttf "Times" "w" .005, 0
                    scale 2.2
                    translate <-.75,0,0>
                    rotate y*dangle 
                    translate -4.0*y
                    pigment{ color Yellow } 
                    finish { phong .8 phong_size 200 ambient 1 }
                  no_shadow }
        translate y*h/2
        }
          text {
            ttf "timrom.ttf" "N" .005, 0
            scale 2.2
            translate <-.5,0,0>
            rotate y*dangle 
            translate 6.5*y+3/cos(brangle)*x
                    pigment{ color rgb <.0,.0,1> } 
                    finish { phong .2 phong_size 20 ambient 1.2 }
           no_shadow
          }

        translate -x*courserad rotate  -y*dangle 
}
sky_sphere {
    pigment {
      gradient y
      color_map {
        [0.000 0.002 color rgb <1.0, 1, 0.8>
                     color rgb <1.0, 1, 0.8>]
        [0.002 0.200 color rgb <0.8, 0.8, 0.6>
                     color rgb <0.2, 0.2, 0.8>]
      }
      scale 2
      translate -1
    }
pigment {
      bozo
      turbulence 0.65
      octaves 6
      omega 0.7
      lambda 2
      color_map {
          [0.0 0.1 color rgb <0.85, 0.85, 0.85>
                   color rgb <0.75, 0.75, 0.75>]
          [0.1 0.5 color rgb <0.75, 0.75, 0.75>
                   color rgbt <1, 1, 1, 1>]
          [0.5 1.0 color rgbt <1, 1, 1, 1>
                   color rgbt <1, 1, 1, 1>]
      }
      scale <0.2, 0.5, 0.2>
    }

    rotate -105*x
    rotate y*180
  }
  plane {  //grassy plain
    y, -.1
    texture {
      pigment { color rgbt <.6,1,.7,.6> }
      normal { bumps 0.3 scale 0.02 }
      finish { phong 50 ambient .6 diffuse .4}
    }    
  }
  plane {
    y, -4 pigment { color Black }    }    

//track
difference{
        cylinder { <0, 0, 0>, <0, h, 0>, courserad+coursewidth/2 }
        cone { <0, -.001, 0>, courserad-coursewidth/2, <0, h+.001, 0>, courserad+coursewidth/2 }
    texture {
      pigment { color rgbt <.3,.3,.3,.6> }
      normal { bumps 0.125 scale 0.125 }
      finish { phong 20 ambient .5 diffuse .8}
    }    
}