// Persistence of Vision Ray Tracer Scene Description File
// File: ?.pov
// Vers: 3.5
// Desc: scence template
// Date: 10/06/04
// Auth: mrg
//

#version 3.5;

#include "colors.inc"
// general math functions and macros
// 
#include "math.inc"

global_settings {
  assumed_gamma 1.2
  ambient_light color rgb <1,1,1>
}
background { color rgb <.05, 0.05, 0.05> }
#declare lclock=clock;
#macro ff(rr)
       ( (rr-y)/pow(vlength(rr-y),3)-(rr+y)/pow(vlength(rr+y),3) )              
#end
#macro dl(ll)
        ( ff(ll)/vlength(ff(ll)) )
#end                            





#declare mrg_blue_texture=
        texture {
          pigment {          // (---surface color---)
                color rgb <0,0,.8>
          }
          finish {           // (---surface finish---)
            ambient 1.0
            specular 0.1     // shiny
          }
        }
#declare mrg_red_texture=
        texture {
          pigment {          // (---surface color---)
                color rgb <.60,0,.0>
          }
          finish {           // (---surface finish---)
            ambient 1.0
            specular 0.1     // shiny
          }
        }
#declare mrg_aqua_texture=
        texture {
          pigment {          // (---surface color---)
                color rgb <.0,.5,.5>
          }
          finish {           // (---surface finish---)
            ambient 1.0
            specular 0.1     // shiny
          }
        }           
                    
sphere { <0, 1, 0>, 0.25 texture{mrg_blue_texture} no_shadow}
sphere { <0, -1, 0>, 0.25 texture{mrg_red_texture} no_shadow}

#declare Nx=8;     //number of lines "emanating from the equator
#declare Ny=Nx/2;  //row index from pole to pole  goes from 0 to Ny
#declare jy=1;     //skip poles for this part
#while(jy<Ny)
        #declare ang=jy/Ny*180;
        #declare llold=y+vrotate(.25*-y,z*ang);
        #declare ds=.01;
        #declare thisline=union{
                #while(llold.y>0)
                        #declare llnew=llold+dl(llold)*ds;
                        cylinder{llold,llnew,.025 texture{mrg_aqua_texture} no_shadow}
                        cylinder{llold,llnew,.025 texture{mrg_aqua_texture} scale<1,-1,1>no_shadow}
                        #declare llold=llnew;
                #end
        }
        #declare nxs=Nx*sin(jy/Ny*pi);
        #declare ix=0;
        #while(ix<nxs)
                object{thisline rotate (ix)/nxs*360*y}
                #declare ix=ix+1;
        #end
        
        #declare jy=jy+1;
#end
cylinder{-5*y,5*y,.025 texture{mrg_aqua_texture} scale<1,-1,1> no_shadow}

#declare lclock=clock+0.0;
#declare trns = function(tt) { (1-cos(pi*max(min(tt,1),0)))/2 }



camera {
  location  (1-trns((lclock-.1)/.8))*<25,15, -35.0>+trns((lclock-.2)/.6)*<2,5, -15.0>
//  location  <25,15, -35.0>
  right     x*image_width/image_height
  look_at   <0.0, 0.0,  0.0>
  angle 30
}

/* 
light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <1, 1, 1>  // light's color
  translate <-30, 30, -30>//place it to the left (neg x), above (pos y) and behind (neg z) vantage point
}
*/
// ----------------------------------------