// Persistence of Vision Ray Tracer Scene Description File
// File: ?.pov
// Vers: 3.5
// Desc: Basic Scene Example
// Date: mm/dd/yy
// Auth: ?
//

#version 3.5;

global_settings {
  assumed_gamma 1.0
    ambient_light rgb <1,1,1> 

}

// ----------------------------------------

#include "colors.inc"
#declare photon_wave=function(x) {
        (.5 - atan(25*x)/(pi))*cos(5*x) + (.5 + atan(25*x)/(pi))*
    exp(-15*abs(x*x))
        }
#declare wstart=-2.5*pi;
#declare wend =.75;
#declare wthick=.05;
#declare wnseg=250;
#declare wxnew=wstart;
#declare wynew=photon_wave(wxnew);
#declare wdx=(wend-wstart)/wnseg;
union{
        #while (wxnew <=wend)
                #declare wxold=wxnew;
                #declare wyold=wynew; 
                #declare wxnew=wxold+wdx;
                #declare wynew=photon_wave(wxnew);
                cylinder{
                        wxold*x+wyold*y,wxnew*x+wynew*y,wthick
                }         
        #end                
        cone{wxnew*x,8*wthick,(wxnew+.75)*x,0 scale <1,1,wthick>}
        texture {pigment { color rgbt <1,1,0,0> } finish{ambient 1 diffuse 1}}
}        
camera {
  location  5*<0, 0, -3.0>
  direction 1.5*z
  right     x*image_width/image_height
  look_at   <0.0, 0.0,  0.0>
}

light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <1, 1, 1>  // light's color
  translate <-30, 30, -30>
}
sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}

// ----------------------------------------